;----------------  Famo用 Ver.2 --------------------



;Ver2.1.0	2001.11.16	By T.HINOKI

		LIST		P=16C84,R=DEC
	PC	EQU	2
	STATUS	EQU	3
	PG	EQU	5
	PORTA	EQU	5
	PORTB	EQU	6
	EEDATA	EQU	8
	EEADR	EQU	9
	TRISA	EQU	H'85'
	TRISB	EQU	H'86'
	EECON1	EQU	H'88'
	EECON2	EQU	H'89'
	RD	EQU	0
	WR	EQU	1
	WREN	EQU	2
	COUNT1	EQU	H'10'
	COUNT2	EQU	H'11'
	PIN1	EQU	H'12'	;1ｃｈ入力パルス幅（左・右）
	PIN2	EQU	H'13'	;２ｃｈ入力パルス幅（前進・後進）
	PIN3	EQU	H'14'	;３ｃｈ入力パルス幅（砲身上下用）
	PIN4	EQU	H'15'	;４ｃｈ入力パルス幅（砲塔旋回用）

	POUT1	EQU	H'16'	;1ｃｈ出力パルス幅（左キャタ速度）
	POUT2	EQU	H'17'	;２ｃｈ出力パルス幅（右キャタ速度）
	POUT3	EQU	H'18'	;３ｃｈ出力パルス幅（砲身上下用）
	POUT4	EQU	H'19'	;４ｃｈ出力パルス幅（砲塔旋回用）
	POUT5	EQU	H'20'	;５ｃｈ出力パルス幅（ブローバックサーボ用）

	KEISAN1	EQU	H'1A'	;計算用変数
	KEISAN2	EQU	H'1B'	;計算用変数
	KEISAN3	EQU	H'1C'	;計算用変数
	HSPEED	EQU	H'1D'	;砲身の上下スピード
	COUNT3	EQU	H'1E'	;砲身の上下スピード作業用
	CENTER3	EQU	H'1F'	;砲塔旋回サーボ停止位置
	COUNT4	EQU	H'21'	;ブローバックサーボの動作カウント用
	COUNT10	EQU	H'22'	;長時間のウエイト用
	COUNT11	EQU	H'23'	;ＴＯＰスピードの時間（揺れに使用）
	COUNT9	EQU	H'24'	;デモ走行作業用
	COUNT8	EQU	H'25'	;機銃発光のタイミング
	CENTER1	EQU	H'26'	;走行用アンプのセンター位置(左)
	CENTER2	EQU	H'27'	;走行用アンプのセンター位置(右)
	SOKUDO	EQU	H'28'	;旋回時の速度ＵＰ値

	ORG	0
	GOTO	START
;------------------------減速ＤＡＴＡ---------------------
	ORG	3
SSOKUDO
	ADDWF	PC,1	;X.Y
	RETLW	4	;0.0
	RETLW	4	;0.1
	RETLW	3	;0.2
	RETLW	3	;0.3
	RETLW	3	;0.4
	RETLW	2	;0.5
	RETLW	2	;0.6
	RETLW	1	;0.7
	RETLW	1	;0.8
	RETLW	1	;0.9
	RETLW	6	;1.0
	RETLW	5	;1.1
	RETLW	4	;1.2
	RETLW	4	;1.3
	RETLW	3	;1.4
	RETLW	3	;1.5
	RETLW	2	;1.6
	RETLW	2	;1.7
	RETLW	1	;1.8
	RETLW	1	;1.9
	RETLW	10	;2.0
	RETLW	9	;2.1
	RETLW	8	;2.2
	RETLW	7	;2.3
	RETLW	6	;2.4
	RETLW	5	;2.5
	RETLW	4	;2.6
	RETLW	3	;2.7
	RETLW	2	;2.8
	RETLW	1	;2.9
	RETLW	15	;3.0
	RETLW	15	;3.1
	RETLW	14	;3.2
	RETLW	12	;3.3
	RETLW	10	;3.4
	RETLW	8	;3.5
	RETLW	6	;3.6
	RETLW	4	;3.7
	RETLW	2	;3.8
	RETLW	1	;3.9
	RETLW	20	;4.0
	RETLW	20	;4.1
	RETLW	17	;4.2
	RETLW	14	;4.3
	RETLW	12	;4.4
	RETLW	10	;4.5
	RETLW	7	;4.6
	RETLW	4	;4.7
	RETLW	3	;4.8
	RETLW	2	;4.9
	RETLW	25	;5.0
	RETLW	24	;5.1
	RETLW	19	;5.2
	RETLW	16	;5.3
	RETLW	13	;5.4
	RETLW	11	;5.5
	RETLW	7	;5.6
	RETLW	4	;5.7
	RETLW	3	;5.8
	RETLW	2	;5.9
	RETLW	30	;6.0
	RETLW	29	;6.1
	RETLW	24	;6.2
	RETLW	20	;6.3
	RETLW	16	;6.4
	RETLW	12	;6.5
	RETLW	8	;6.6
	RETLW	5	;6.7
	RETLW	4	;6.8
	RETLW	3	;6.9
	RETLW	35	;7.0
	RETLW	34	;7.1
	RETLW	29	;7.2
	RETLW	23	;7.3
	RETLW	15	;7.4
	RETLW	10	;7.5
	RETLW	6	;7.6
	RETLW	4	;7.7
	RETLW	3	;7.8
	RETLW	2	;7.9
	RETLW	40	;8.0
	RETLW	38	;8.1
	RETLW	32	;8.2
	RETLW	26	;8.3
	RETLW	20	;8.4
	RETLW	13	;8.5
	RETLW	8	;8.6
	RETLW	5	;8.7
	RETLW	3	;8.8
	RETLW	2	;8.9
	RETLW	45	;9.0
	RETLW	40	;9.1
	RETLW	35	;9.2
	RETLW	30	;9.3
	RETLW	25	;9.4
	RETLW	20	;9.5
	RETLW	10	;9.6
	RETLW	6	;9.7
	RETLW	4	;9.8
	RETLW	3	;9.9
	RETLW	45	;9.0
	RETLW	40	;9.1
	RETLW	35	;9.2
	RETLW	30	;9.3
	RETLW	25	;9.4
	RETLW	20	;9.5
	RETLW	15	;9.6
	RETLW	10	;9.7
	RETLW	2	;9.8
	RETLW	1	;9.9
;------------------------　片側減速時の反対側補正値　-------
SSOKUDO2
	ADDWF	PC,1	;X
	RETLW	1	;0
	RETLW	1	;1
	RETLW	2	;2
	RETLW	3	;3
	RETLW	4	;4
	RETLW	6	;5
	RETLW	8	;6
	RETLW	10	;7
	RETLW	12	;8
	RETLW	0	;9
	RETLW	0	;0

;-------------------------------------------------------
START
	CLRF	PORTB		;クリア PORTB
	BSF	STATUS,PG	;Change Page1
	MOVLW	B'1111'		;TRISA=F  All Input
	MOVWF	TRISA
	CLRF	TRISB		;TRISB=0  All output
	BCF	STATUS,PG	;Change Page0


LOOP00
	MOVLW	150		;砲塔旋回値を１５０（停止）に設定
	MOVWF	CENTER3

LOOP000

;-----------------  砲塔旋回サーボの停止位置設定（電源投入時、前進後進スティックが１番下の時に設定登録）
	BSF	PORTB,6		;PULS off

	CALL	PULSOFF		;電源入れていきなり受け取るとノイズがあるかも...ちょっと待とう
	CALL	PULSIN2		;2chパルス幅取得

	MOVLW	180		;前後スティックが180以上だったら設定開始
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<180はLOOP01へ
	GOTO	LOOP01		;

	BSF	PORTB,5		;LED on（設定中は機銃用ＬＥＤを点灯）

LOOP0
	CALL	PULSIN2		;2chパルス幅取得

	MOVLW	150		;
	MOVWF	PIN4

	MOVF	PIN4,0		;-------  プロポの左右スティック値を
	MOVWF	POUT4		;-------  そのまま砲塔旋回サーボへ出力
	BSF	PORTB,3		;PULS3 on
	MOVF	POUT4,0		;
	CALL	TIM25		;
	BCF	PORTB,3		;PULS off
;
	BSF	PORTB,0		;PULS1 on
	MOVLW	150		;アンプのセンター位置
	CALL	TIM25		;
	BCF	PORTB,0		;PULS off
;
	BSF	PORTB,1		;PULS2 on
	MOVF	150		;アンプのセンター位置
	CALL	TIM25		;
	BCF	PORTB,1		;PULS off

	CALL	PULSOFF
	CALL	PULSOFF

	MOVLW	120		;前後スティックが120以下だったら設定終了
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=120はLOOP0へ
	GOTO	LOOP0		;

	BCF	PORTB,5		;LED off（機銃用のＬＥＤを消す）
	MOVF	PIN4,0		;W=PIN4
	MOVWF	CENTER3		;CENTER3=W	センターの位置を記憶


LOOP01



;------------走行用アンプのセンター位置
	MOVLW	150		;１５０（停止）に設定
	MOVWF	CENTER1
	MOVWF	CENTER2


;-------------------メインルーチン -------------
LOOP1

	CALL	PULSIN1		;1chパルス幅取得
	CALL	PULSIN2		;2chパルス幅取得

	MOVF	PIN2,0
	MOVWF	POUT1
	MOVWF	POUT2

;-------------------後部ハンドルの逆転ルーチン -------------

	MOVF	PIN1,0
	MOVLW	165		;左右スティックが165以下だったら
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=165は
	GOTO	STEA02		;

	MOVLW	135		;左右スティックが135以上だったら停止
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<135は
	GOTO	STEA02		;

	MOVF	PIN1,0
	MOVWF	POUT3
	GOTO	STEA03		;

STEA02
	MOVF	PIN1,0
	SUBLW	250		;250-角度
	ADDLW	50
	MOVWF	POUT3

STEA03


;--------停止中
	MOVLW	152		;前後スティックが153以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=153はNEXT51へ
	GOTO	HOSEI01		;
	MOVLW	148		;前後スティックが148以上だったら停止
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<148はNEXT51へ
	GOTO	HOSEI02		;
	MOVLW	150		;左右中間(停止)に
	MOVWF	POUT1
	MOVWF	POUT2
	MOVWF	PIN2
	GOTO	PULSOUT		;
;	GOTO	LOOP1		;パルス送らないときは

HOSEI01
	MOVLW	180		;前後スティックが180以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=180はNEXT51へ
	GOTO	NEXT51		;
;-------微速補正

	MOVLW	4		;
	SUBWF	PIN2,1		;PIN2=PIN2-W
	MOVLW	151		;151以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=151はHOSEI03へ
	GOTO	HOSEI03		;

	MOVLW	151		;
	MOVWF	PIN2		;
HOSEI03
	GOTO	HOSEI04		;

HOSEI02
	MOVLW	120		;前後スティックが120以上だったら
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<120はNEXT51へ
	GOTO	NEXT51		;

	MOVLW	4		;
	ADDWF	PIN2,1		;PIN2=PIN2+W

	MOVLW	150		;150以上だったら
	SUBWF	PIN2,0		;
	BTFSS	STATUS,0	;(CY=0) PIN2<150はHOSEI04へ
	GOTO	HOSEI04		;
	MOVLW	149		;
	MOVWF	PIN2		;
HOSEI04

	MOVF	PIN2,0		;W=PIN2
	MOVWF	POUT1
	MOVWF	POUT2
	GOTO	NEXT51		;

NEXT51
;--------左旋回
	MOVLW	148		;左右スティックが147以下だったら
	SUBWF	PIN1,0		;
	BTFSC	STATUS,0	;(CY=1) PIN1>=148はNEXT7へ
	GOTO	NEXT7		;


;--------前進
	MOVLW	150		;前後スティックが150以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=150はNEXT62へ
	GOTO	NEXT62		;

	MOVF	POUT1,0		;W=POUT1
	SUBLW	150		;W=150-速度
	CALL	WARU10		;((150-速度)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVF	PIN1,0		;W=PIN1
	SUBLW	150		;150-角度
	CALL	WARU5		;(150-角度)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	KEISAN3		;KEISAN3=W
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;W=150
	MOVWF	POUT1		;POUT1=W
	MOVF	KEISAN3,0	;W=KEISAN3
	SUBWF	POUT1,1		;POUT1=POUT1-W

;	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
;	SUBWF	POUT2,1		;POUT2=POUT2-W

	GOTO	PULSOUT

NEXT62
;--------後進
	MOVLW	150		;W=150
	SUBWF	POUT1,0		;W=速度-150

	CALL	WARU10		;((速度-150)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVF	PIN1,0
	SUBLW	150		;150-角度
	CALL	WARU5		;(150-角度)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	POUT1		;POUT1=W
	MOVF	CENTER1,0	;W=CENTER1
;	MOVLW	150		;W=150
	ADDWF	POUT1,1		;POUT1=POUT1+W

;	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
;	ADDWF	POUT2,1		;POUT2=POUT2+W

	GOTO	PULSOUT

NEXT7
;--------右旋回
	MOVLW	153		;左右スティックが153以上だったら
	SUBWF	PIN1,0		;
	BTFSS	STATUS,0	;(CY=0) PIN1<153はNEXT8へ
	GOTO	NEXT8		;
;--------前進
	MOVLW	150		;前後スティックが150以下だったら
	SUBWF	PIN2,0		;
	BTFSC	STATUS,0	;(CY=1) PIN2>=150はNEXT72へ
	GOTO	NEXT72		;

	MOVF	POUT2,0
	SUBLW	150		;150-速度

	CALL	WARU10		;((150-速度)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVLW	150
	SUBWF	PIN1,0		;角度-150
	CALL	WARU5		;(角度-150)÷5
	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	KEISAN3		;KEISAN3=W
	MOVF	CENTER2,0	;W=CENTER2
;	MOVLW	150		;W=150
	MOVWF	POUT2		;POUT2=W
	MOVF	KEISAN3,0	;W=KEISAN3
	SUBWF	POUT2,1		;POUT2=POUT2-W
;	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
;	SUBWF	POUT1,1		;POUT1=POUT1-W

	GOTO	PULSOUT

NEXT72

;--------後進
	MOVLW	150		;W=150
	SUBWF	POUT1,0		;速度-150

	CALL	WARU10		;((速度-150)÷10)×10
	MOVWF	KEISAN3		;KEISAN3=W

	MOVLW	150
	SUBWF	PIN1,0		;角度-150
	CALL	WARU5		;(角度-150)÷5

	MOVF	KEISAN2,0	;W=KEISAN2
	ADDWF	KEISAN3,1	;KEISAN3=KEISAN3+W
	MOVF	KEISAN3,0	;W=KEISAN3
	CALL	SSOKUDO		;データ読み込み

	MOVWF	POUT2		;POUT2=W
	MOVF	CENTER2,0	;W=CENTER2
;	MOVLW	150		;W=150
	ADDWF	POUT2,1		;POUT2=POUT2+W
;	MOVF	SOKUDO,0	;W=SOKUDO	速度補正
;	ADDWF	POUT1,1		;POUT1=POUT1+W

	GOTO	PULSOUT

NEXT8

PULSOUT

	CALL	PULSOUT99

	CALL	PULSOFF

	GOTO	LOOP1

;======================== パルスＯＵＴ
PULSOUT99
;--------停止中はパルスを出さない
;	MOVLW	154		;前後スティックが154以下だったら
;	SUBWF	PIN2,0		;
;	BTFSC	STATUS,0	;(CY=1) PIN2>=154はNEXT51へ
;	GOTO	PULSOUT01
;
;	MOVLW	147		;前後スティックが147以上だったら停止
;	SUBWF	PIN2,0		;
;	BTFSS	STATUS,0	;(CY=0) PIN2<147はNEXT51へ
;	GOTO	PULSOUT01	;
;	RETURN
PULSOUT01
	BSF	PORTB,0		;PULS1 on
	MOVF	POUT1,0
	CALL	TIM25
	BCF	PORTB,0		;PULS off

	CALL	PULSOFF

	BSF	PORTB,1		;PULS2 on
	MOVF	POUT2,0
	CALL	TIM25
	BCF	PORTB,1		;PULS off

;	CALL	PULSOFF

	BSF	PORTB,2		;PULS3 on
	MOVF	POUT3,0
	CALL	TIM25
	BCF	PORTB,2		;PULS off
	RETURN


;***********　Ｗ÷５＝Ｗ
WARU5
	MOVWF	KEISAN1		;Ｗ=KEISAN1
	MOVLW	0		;
	MOVWF	KEISAN2		;カウンター初期化
	MOVF	KEISAN1,0	;W=KEISAN1
	SUBLW	4
	BTFSS	STATUS,0	;W>4
	GOTO	WARU51
	RETURN
WARU51
	MOVLW	5		;
	SUBWF	KEISAN1,1
	BTFSS	STATUS,0	;CY=0　で終了
	RETURN
	INCF	KEISAN2,1	;KEISAN2=KEISAN2+1
	GOTO	WARU51

;***********　(Ｗ÷5 )×10＝KEISAN2
WARU10
	MOVWF	KEISAN1		;KEISAN1=W
	MOVLW	0		;
	MOVWF	KEISAN2		;カウンター初期化
	MOVF	KEISAN1,0	;W=KEISAN1
	SUBLW	4
	BTFSS	STATUS,0	;W>4
	GOTO	WARU101
	MOVLW	0		;
	MOVWF	SOKUDO		;速度＋分を0
	RETURN

WARU101
	MOVLW	5		;
	SUBWF	KEISAN1,1
	BTFSS	STATUS,0	;CY=0　で終了
	GOTO	KAKEL5
	INCF	KEISAN2,1	;KEISAN2=KEISAN2+1
	GOTO	WARU101

;***********　KEISAN2×10＝W
KAKEL5
	MOVF	KEISAN2,0	;W=KEISAN2
	CALL	SSOKUDO2
	MOVWF	SOKUDO		;SOKUDO=W

	MOVLW	0		;
	MOVWF	KEISAN1		;カウンター初期化
KAKELU51
	DECFSZ	KEISAN2,1	;KEISAN2=KEISAN2-1
	GOTO	KAKELU52	;KEISAN2が0になるまで繰り返し
	MOVF	KEISAN1,0	;W=KEISAN1
	RETURN
KAKELU52
	MOVLW	10		;
	ADDWF	KEISAN1,1		;KEISAN1=KEISAN1+W
	GOTO	KAKELU51


;-------------  20サイクルタイマー（実際は19サイクル）
TIM20
	GOTO	$+1	;2
	GOTO	$+1	;+2=4
	GOTO	$+1	;+2=6
	GOTO	$+1	;+2=8
	GOTO	$+1	;+2=10
	GOTO	$+1	;+2=12
	GOTO	$+1	;+2=14
	GOTO	$+1	;+2=16
	NOP		;+1=17
	RETURN		;+2=19

;-------------  Ｗレジスタ分のカウントタイマー(1カウント=25サイクル)×Ｗ
TIM25
	MOVWF	COUNT1		;1+1=2
TIM26
	CALL	TIM20		;19+2=21
	NOP			;+1=22
	DECFSZ	COUNT1,1	;+1=23
	GOTO	TIM26		;+2=25
	RETURN			;+1+(W*25)+2-1

;-----------パルスとパルスの間の空き時間-----------------
PULSOFF
	MOVLW	150
	CALL	TIM25		;
;	MOVLW	255
;	CALL	TIM25		;
	RETURN

;-------------  時間稼ぎ(1/4秒×Ｗ)
TIM90
	MOVWF	COUNT10		;
TIM91
	MOVLW	50
	MOVWF	COUNT9		;
TIM92
	MOVLW	255
	CALL	TIM25		;
	DECFSZ	COUNT9,1	;
	GOTO	TIM92		;
	DECFSZ	COUNT10,1	;
	GOTO	TIM91		;
	RETURN			;

;-----------1CHパルス幅測定（PIN1）左右のステック-----------
PULSIN1
	BTFSS	PORTA,0		;OFF の時
	GOTO	PULSIN1		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN1		;カウンター初期化
PULSIN11
	CALL	TIM20		;20サイクル待ち	(19+2)
	INCF	PIN1,1		;PIN1=PIN1+1	(22)
	BTFSC	PORTA,0		;ＯＮの時は	(23)
	GOTO	PULSIN11	;カウント継続	(25)

	MOVLW	90		;カウントが90以下だったら
	SUBWF	PIN1,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN1<90
	GOTO	PULSIN1		;
	RETURN

;-----------2CHパルス幅測定（PIN2）前進・後進のスティック-----------
PULSIN2
	BTFSS	PORTA,1		;OFF の時
	GOTO	PULSIN2		;入力待ちループ
	MOVLW	0		;
	MOVWF	PIN2		;カウンター初期化
PULSIN21
	CALL	TIM20		;20サイクル待ち
	INCF	PIN2,1		;PIN1=PIN1+1
	BTFSC	PORTA,1		;ＯＮの時は、
	GOTO	PULSIN21	;カウント継続

	MOVLW	90		;カウントが90以下だったら
	SUBWF	PIN2,0		;カウントしなおし！
	BTFSS	STATUS,0	;(CY=0) PIN2<90
	GOTO	PULSIN2		;
	RETURN



	END
